Bird-Soft Weblog: ゲーム作成関連 - 任意の方向に弾を飛ばす(第1回) -

今回は、シューティングゲームなどで使えると思われる、敵が自機の方向に弾を飛ばすというような方法のサンプルと、その解説をしていきます。

サンプルソースはつぎのようになります。
※ＨＳＰ3.0で動作します。
ゲームづくりには基本となる部分です。

// 弾発射サンプル
//
// http://www.bird-soft.net/
// 2006 BIRD

//--------------各種設定(初期化)--------------
 	speed = 2.0  // 弾の移動スピード
	x = 200.0   //自分の初期座標X
	y = 150.0   //自分の初期座標Y
	ex = 200.0  //敵の弾の座標X
	ey = 200.0  //敵の弾の座標Y
	timer = 0  //ゲーム進行用のタイマー

//--------------メインループ--------------
*main
	redraw 0

	gosub *hyouji  //デバッグ情報と弾の表示
	gosub *ziki_idou  //キーボードの状況をチェックして自機を移動させる
	;gosub *cal_kakudo  //ここのコメントをはずせば誘導弾になる

 	ex += dx  //弾を移動させる(X座標)
    	ey += dy  //弾を移動させる(Y座標)
	timer++  //タイマーを増やす

	redraw 1
    	await 10
goto *main

//--------------サブルーチン--------------

//角度計算(弾の移動方向を決める) (重要度：高)
*cal_kakudo
	length_x = x - ex  // X座標の差を求める
	length_y = y - ey  // Y座標の差を求める
	rad = atan(length_y,length_x)  // ターゲットとの角度を求める
	dx = double (cos(rad)) * speed	// x方向の移動量を計算
	dy = double (sin(rad)) * speed	// y方向の移動量を計算
return

//青い四角をキーボードで移動する
*ziki_idou
	stick key,15
	if key&1 {  //カーソルキー左(←)
		x = x-3
	}
	if key&2 {  //カーソルキー上(↑)
		y = y-3
	}
	if key&4 {  //カーソルキー右(→)
		x = x+3
	}
	if key&8 {  //カーソルキー下(↓)
		y = y+3
	}
	if key&16 {  //スペースキー
		gosub *attack
	}
return

//弾を発射
*attack
	ex = 200.0 : ey = 200.0  //弾の位置をセット
	gosub *cal_kakudo
return

//文字などを表示するサブルーチン(重要度：低)
*hyouji
	color 255,255,255 : boxf  //背景を白で消す
	pos 5,5 : color : print "Timer:"+timer+" / 自機X:"+x+"自機Y:"+y
	print "弾X:"+ex+"弾Y:"+ey+" / speed:"+speed

	color 230,230,255 : boxf 0,43,170,130
	color 0,0,0 : print "スペースキーを押すと"
	color 0,200,0 : print "敵が"
	color 0,0,255 : print "自機に向けて"
	color 255,0,0 : print "弾を発射"
	color 0,0,0 : print "します。"

	color 0,0,255 : boxf x,y,x+10,y+10  //自機(青い四角)
    	color 255,0,0 : circle ex,ey,ex+10,ey+10  //弾(赤い丸)
	color 0,200,0: boxf 200,200,200+10,200+10  //敵(緑の四角)

return

◆スクリーンショット

◆解説

*cal_kakudo

というサブルーチンがポイントです。ここでの処理が今回一番のポイントである

弾の発射方向の計算

をしている部分です。

※長くなるので2回目へ続きます・・・

応援お願いします(人気blogランキングへ)

Bird-Soft Weblog

プログラミング(Perl,C#,HSP,PSoC)、おすすめゲーム、など、趣味についてのんびり更新。

ゲーム作成関連 - 任意の方向に弾を飛ばす(第1回) -

トラックバック

コメントを投稿